Myriad Lite SFX Server

Myriad_Lite_SFX_Server-v0.0.0-20111008.lsl

// Myriad_Lite_SFX_Server-v0.0.0-20111006.lsl
// The Myriad RPG System was designed, written, and illustrated by Ashok Desai
// Myriad RPG licensed under the Creative Commons Attribution 2.0 UK: England and Wales
// http://creativecommons.org/licenses/by/2.0/uk/
// Myriad Lite software Copyright (c) 2011 by Allen Kerensky (OSG/SL)
// Myriad Lite licensed under the
// Creative Commons Attribution-Share Alike-Non-Commercial 3.0 Unported
// http://creativecommons.org/licenses/by-nc-sa/3.0/

// CONSTANTS - DO NOT CHANGE DURING RUN
string VERSION = "0.0.0"; // Allen Kerensky's script version
string VERSIONDATE = "20111008"; // Allen Kerensky's script yyyymmdd
integer CHAN_MYRIAD = -999; // regionwide channel for Myriad events
string CARD = "Myriad_Lite_SFX-v0.0.0-20100326.csv"; // notecard data table

// RUNTIME GLOBALS - CAN CHANGE DURING RUN
integer HAND_MYRIAD; // llListenRemove handle for Myriad regional channel

list EFFECTS; // names of the special effect abilities
list TYPES; // types of SFX, indexed by name order
list ACTIVATIONS; // activation rules for SFX, indexed by name order
list DESCRIPTIONS; // SFX descriptions indexed, by name order

integer LINE = 0; // reading line number
key QUERY = NULL_KEY; // track notecard queries

// DEBUG - show debug messages
DEBUG(string dmessage) {
    llOwnerSay("DEBUG: "+dmessage);
}

// SETUP - begin
SETUP() {
    if ( HAND_MYRIAD != 0 ) llListenRemove(HAND_MYRIAD); // is there already a listener? clear it  
    HAND_MYRIAD = llListen(CHAN_MYRIAD,"",NULL_KEY,""); // start region channel listener
    DEBUG("Special Effect (SFX) server "+VERSION+" "+VERSIONDATE+" loading Effects. Please wait..."); // tell player we're waiting for data server
    QUERY = llGetNotecardLine(CARD,LINE++); // ask for line from notecard and advance to next line
}

// RESET - reload
RESET() {
    llResetScript(); // now reset
}

LIST_EFFECTS(key id) {
    integer replyto = (integer)("0x"+llGetSubString((string)id,0,6)); // calculate requestor-specific chat channel to reply to
    // we have to work around llRegionSay max string length 1023 characters
    integer items = llGetListLength(EFFECTS); // how many total items to send?
    integer count; // which item are we processing now?
    string out = "EFFECTS|"; // start an output list
    integer firstflag = TRUE; // is this first item in new list?
    while (count < items ) { // do we still have items in list to send?
        string name = llList2String(EFFECTS,count); // get the name of current item
        if (  llStringLength(out+","+name) <= 1016) { // is our output list under the string length limit?
            if ( firstflag == TRUE ) { // first item in list does not need a comma prefix
                out += name; // add this item as first in the output list
                firstflag = FALSE; // turn off first flag since next item won't be
            } else { // not first item in list, prefix with comma
                out += ","+name; // add a comma and this effect to existing list
            }
        } else { // output string > 1016 chars long
            llRegionSay(replyto,out); // send current output string
            out = "EFFECTS|"+name; // start a new one and add current item to that
        }
        count++; // done putting this item in a list, set counter to next
    }   
    llRegionSay(replyto,out); // say last line of output            
}

GET_EFFECT(key id,string msg) {
    integer replyto = (integer)("0x"+llGetSubString((string)id,0,6)); // calculate requestor-specific chat channel to reply to
    list tokens = llParseString2List(msg,["|"],[]); // split msg into list around pipe symbols
    string effect = llList2String(tokens,1); // the name of the item to get
    integer listpos = llListFindList(EFFECTS,[effect]); // get the position of that item in the list
    string reply = "EFFECTS"; // start output item data NO PLURAL here - we're sending 1 effect
    if ( listpos != -1 ) { // was item name in the list?
        reply += "|NAME="+llList2String(EFFECTS,listpos); // add effect name to output
        reply += "|TYPE="+llList2String(TYPES,listpos); // add effect type to output
        reply += "|ACTIVATION="+llList2String(ACTIVATIONS,listpos); // add effect activation rules to output
        reply += "|DESCRIPTION="+llList2String(DESCRIPTIONS,listpos); // add effect description to output
        llRegionSay(replyto,reply); // send it to requestor FIXME what if output greater than 1016 chars?
    } else {
        llRegionSay(replyto,"EFFECTS|ERROR=Requested effect ("+effect+") not found"); // item requested does not exist, return an error
    }
}

SET_EFFECT() {
    // FIXME - do we need this?
}

// DEFAULT STATE
default {

    // STATE ENTRY - called on Reset
    state_entry() {
        SETUP(); // show credits and start notecard data load
    }

    // on_rez - when rezzed to ground or from inventory as attachment during login
    on_rez(integer params) {
        params = 0; // LSLINT
        RESET(); // force to go through state entry
    }

    // attach - when attached or detached from inventory or during login
    attach(key id) {
        id = NULL_KEY; // LSLINT
        RESET(); // force to go through state entry
    }

    // dataserver called for each line of notecard requested
    dataserver(key queryid,string data) {
        if ( queryid == QUERY ) { // dataserver gave us line we asked for?
            if ( data != EOF ) { // we're not at end of notecard file?
                if ( llGetSubString(data,0,0) == "#" ) { // does this line start with comment mark?
                    QUERY = llGetNotecardLine(CARD,LINE++); // ignore comment and ask for the next line
                    return;
                }
                // Parse non-comment lines in keyword = value[,value,...] format
                list fields = llParseString2List(data,[","],[]); // break line of text into = delimited fields
                EFFECTS         = EFFECTS + [llStringTrim(llList2String(fields,0),STRING_TRIM)]; // add effect name field to list
                TYPES           = TYPES + [llStringTrim(llList2String(fields,1),STRING_TRIM)]; // add effect type field to list
                ACTIVATIONS     = ACTIVATIONS+ [llStringTrim(llList2String(fields,2),STRING_TRIM)]; // add effect activation rule field to list
                DESCRIPTIONS    = DESCRIPTIONS + [llStringTrim(llList2String(fields,3),STRING_TRIM)]; // add effect description field to list
                QUERY = llGetNotecardLine(CARD,LINE++); // finished with known keywords, get next line
            } else { // end of notecard
                DEBUG("SFX loaded. Server ready. Free Memory: "+(string)llGetFreeMemory()); // done, ready to serve            
            } // end if data not equal eof
        } // end if query id equal
    } // end if data server event
    
    listen(integer channel,string name,key id,string msg) {
        channel = 0; // LSLINT
        name = ""; // LSLINT        
        list tokens = llParseString2List(msg,["|"],[ ]); // split msg into list around pipe symbols
        string command = llList2String(tokens,0); // first field is some sort of command
        if ( command == "LIST_EFFECTS" ) { // is this a list all SFX request?
            LIST_EFFECTS(id); // call it
            return; // return early instead of processing more
        }
        if ( command == "GET_EFFECT" ) { // GET_EFFECT|string effectname
            GET_EFFECT(id,msg); // call it
            return; // return early instead of processing more
        }
        if ( command == "SET_EFFECT" ) { // is this a set-effect request
            SET_EFFECT(); // call it
            return; // return early in case we add more later
        }
    }
} // end default state