Revision as of 10:24, 6 February 2012

Myriad Lite Boons Server

Myriad_Lite_Boons_Server-v0.0.1-20120124.lsl

// Myriad_Lite_Boon_Server-v0.0.1-20120124.lsl
// The Myriad RPG System was designed, written, and illustrated by Ashok Desai
// Myriad RPG licensed under the Creative Commons Attribution 2.0 UK: England and Wales
// http://creativecommons.org/licenses/by/2.0/uk/
// Myriad Lite software Copyright (c) 2011 by Allen Kerensky (OSG/SL)
// Myriad Lite licensed under the
// Creative Commons Attribution-Share Alike-Non-Commercial 3.0 Unported
// http://creativecommons.org/licenses/by-nc-sa/3.0/

// CONSTANTS - DO NOT CHANGE DURING RUN
string VERSION = "0.0.1"; // Allen Kerensky's script version
string VERSIONDATE = "20120124"; // Allen Kerensky's script yyyymmdd
integer CHAN_MYRIAD = -999; // regionwide channel for Myriad events
string CARD = "Myriad_Lite_Boons-v0.0.0-20100326.csv"; // notecard data table

// RUNTIME GLOBALS - CAN CHANGE DURING RUN
integer HAND_MYRIAD; // llListenRemove handle for Myriad regional channel

list BOONNAMES; // names of boons loaded
list TYPES; // boon types indexed in name order
list GP_COSTS; // GP cost for boon, indexed by name order
list MAX_LEVELS; // max levels for boon, indexed by name order
list DESCRIPTIONS; // boon description, indexed by name order

integer LINE = 0; // reading line number
key QUERY = NULL_KEY; // track notecard queries

// DEBUG - show debug messages
DEBUG(string dmessage) {
    llOwnerSay("DEBUG: "+dmessage);
}

// SETUP - begin
SETUP() {
    if ( HAND_MYRIAD != 0 ) llListenRemove(HAND_MYRIAD); // is there already a listener? clear it
    HAND_MYRIAD = llListen(CHAN_MYRIAD,"",NULL_KEY,""); // start region channel listener
    DEBUG("Boon Server "+VERSION+" "+VERSIONDATE+" loading Boons. Please wait..."); // tell player we're waiting for data server
    QUERY = llGetNotecardLine(CARD,LINE++); // ask for line from notecard and advance to next line
}

// RESET - reload
RESET() {
    llResetScript(); // now reset
}

LIST_BOONS(key id) {
    integer replyto = (integer)("0x"+llGetSubString((string)id,0,6)); // calculate specific user channel to reply to
    // we have to work around llRegionSay max string length 1023 characters
    integer items = llGetListLength(BOONNAMES); // how many total items to send?
    integer count; // which item are we processing now?
    string out = "BOONS|"; // start an output list
    integer firstflag = TRUE; // is this first item in new list?
    while (count < items ) { // do we still have items in list to send?
        string name = llList2String(BOONNAMES,count); // get the name of current boon
        if ( llStringLength(out+","+name) <= 1016) { // is our output list under the string length limit?
            if ( firstflag == TRUE ) { // first item in list does not need a comma prefix
                out += name; // add this item as first in the output list
                firstflag = FALSE; // turn off first flag since next item won't be
            } else { // not first item in list, prefix with comma
                out += ","+name; // add a comma and this boon to existing list
            }
        } else { // output string > 1016 chars long
            llRegionSay(replyto,out); // send current output string
            out = "BOONS|"+name; // start a new one and add current item to that
        }
        count++; // done putting this item in a list, set counter to next
    }   
    llRegionSay(replyto,out); // say last line of output
}

GET_BOON(key id,string msg) {
    integer replyto = (integer)("0x"+llGetSubString((string)id,0,6)); // calculate requestor-specific chat channel to reply to
    list tokens = llParseString2List(msg,["|"],[]); // split msg into list around pipe symbols
    string boon = llList2String(tokens,1); // the name of the boon to get
    integer listpos = llListFindList(BOONNAMES,[boon]); // get the position of that boon in the list
    string reply = "BOON"; // start output boon data NO PLURAL here - we're sending 1 boon
    if ( listpos != -1 ) { // was boon name in the list?
        reply += "|NAME="+llList2String(BOONNAMES,listpos); // add name field to output
        reply += "|TYPE="+llList2String(TYPES,listpos); // add type field to output
        reply += "|GP_COST="+llList2String(GP_COSTS,listpos); // add cost field to output
        reply += "|MAX_LEVEL="+llList2String(MAX_LEVELS,listpos); // add max level to output
        reply += "|DESCRIPTION="+llList2String(DESCRIPTIONS,listpos); // add description to output
        llRegionSay(replyto,reply); // send it to requestor FIXME what if output greater than 1016 chars?
    } else {
        llRegionSay(replyto,"SKILL|ERROR=Requested Boon ("+boon+") not found"); // boon requested does not exist, return an error
    }
}

SET_BOON() {
    // FIXME - do we need this?
}

// DEFAULT STATE
default {

    // STATE ENTRY - called on Reset
    state_entry() {
        SETUP(); // show credits and start notecard data load
    }

    // on_rez - when rezzed to ground or from inventory as attachment during login
    on_rez(integer params) {
        params = 0; // LSLINT
        RESET(); // force to go through state entry
    }

    // attach - when attached or detached from inventory or during login
    attach(key id) {
        id = NULL_KEY; // LSLINT
        RESET(); // force to go through state entry
    }

    // dataserver called for each line of notecard requested
    dataserver(key queryid,string data) {
        if ( queryid == QUERY ) { // dataserver gave us line we asked for?
            if ( data != EOF ) { // we're not at end of notecard file?
                if ( llGetSubString(data,0,0) == "#" ) { // does this line start with comment mark?
                    QUERY = llGetNotecardLine(CARD,LINE++); // ignore comment and ask for the next line
                    return; // return early since we skipping comments
                }
                // Parse non-comment lines in keyword = value[,value,...] format
                list fields = llParseString2List(data,[","],[]); // break line of text into = delimited fields
                BOONNAMES       = BOONNAMES + [llStringTrim(llList2String(fields,0),STRING_TRIM)]; // add name of boon to name list
                TYPES           = TYPES + [llStringTrim(llList2String(fields,1),STRING_TRIM)]; // add type of boon to type list
                GP_COSTS        = GP_COSTS + [llStringTrim(llList2String(fields,2),STRING_TRIM)]; // add cost of boon to cost list
                MAX_LEVELS      = MAX_LEVELS + [llStringTrim(llList2String(fields,3),STRING_TRIM)]; // add max level of boon to max level list
                DESCRIPTIONS    = DESCRIPTIONS + [llStringTrim(llList2String(fields,4),STRING_TRIM)]; // add description of boon to description list
                QUERY = llGetNotecardLine(CARD,LINE++); // finished with known keywords, get next line
            } else { // end of notecard
                DEBUG("Boons Loaded. Server ready. Free Memory: "+(string)llGetFreeMemory()); // done, ready to serve
            } // end if data not equal eof
        } // end if query id equal
    } // end if data server event
    
    listen(integer channel,string name,key id,string msg) {
        channel = 0; // LSLINT
        name = ""; // LSLINT
        list tokens = llParseString2List(msg,["|"],[ ]); // split msg into list around pipe symbols
        string command = llList2String(tokens,0); // first field is some sort of command
        if ( command == "LIST_BOONS" ) { // is this a list all boon names request
            LIST_BOONS(id); // call it
            return; // return early instead of processing more
        }
        if ( command == "GET_BOON" ) { // GET_BOON|string boonname
            GET_BOON(id,msg); // call it
            return; // return early instead of processing more
        }
        if ( command == "SET_BOON" ) { // is this a set-boon request?
            SET_BOON(); // call it
            return; // return early in case we add more later
        }
    }
} // end default state